ARTICLE · 1018696
通达信【中轴多因子】多条件统计指标源码分享:主图+副图+选股三件套
本文仅供学习交流，不构成任何投资建议！
今天公式手记分享一套“中轴多因子”主图+副图+选股公式。所有条件仅对历史K线中的价格、成交量、均线等参数做统计描述，不涉及任何资金行为判断。
本文所有指标公式，是对历史行情数据的统计描述，旨在分享通达信公式编写逻辑与技术思路。不构成任何投资建议，不作为买卖依据。股市有风险，入市需谨慎。
一、逻辑说明：
1. 主图：以价格中轴（收盘价衍生平滑线）为参考，价格在线上方运行标记为偏强统计区间，大阴/大阳用不同色柱区分振幅统计；
2. 副图：综合RSI区间、CCI位置、MACD方向、均价与成本线的交叉关系，四项子条件同时吻合时标记"多条件吻合"；
3. 选股：主图转强条件 + 副图多因子标记同日成立，配合风控筛选观察池。
二、观察方法：
1. 主图价格站上中轴参考线 + 当日涨幅统计达标 → 进入观察名单；
2. 副图出现"多条件吻合"标记 → 说明多项历史统计条件同时吻合；
3. 标记出现后，继续观察后续2-3日价格是否维持在中轴上方、量能是否温和。若再次跌破中轴，仅说明本次统计条件减弱。
三、重要说明：
1. 本套公式未使用ZIG、REFX、BACKSET等未来函数，信号基于已收盘数据，不重绘；
2. 指标仅是对历史数据的统计描述，不预测涨跌、不给出买卖点、不承诺成功率；
3. 本文仅分享通达信公式编写技术，不涉及付费群、不带单、不私信荐股。
本文所有内容仅为通达信公式编写的技术分享，所有信号均为历史数据回测的统计结果，不构成任何投资建议，不涉及任何金融产品营销，不作为买卖依据。
（注：以下源码仅供编程技术研究，不涉及任何买卖建议）。
1、中轴观察主图公式：
{中轴观察·主图-公式手记-原创}
A1:=REF(EMA((H+L+C)/3,9),1);
A2:=EMA(HHV(HIGH,9),3);
A3:=EMA(LLV(LOW,9),3);
中轴参考:EMA(A1*2-A3,5),COLORMAGENTA,LINETHICK2;
弱势线:IF(CLOSE<中轴参考,中轴参考,DRAWNULL),COLORLIGREEN,LINETHICK2;
DRAWKLINE(HIGH,OPEN,LOW,CLOSE);
大阴统计:=(REF(CLOSE,1)-CLOSE)/REF(CLOSE,1)*100>=10;
STICKLINE(大阴统计,CLOSE,OPEN,2,0),COLORGREEN;
涨幅异动:=(CLOSE/REF(CLOSE,1)-1)*100>7;
转强条件:=OPEN<中轴参考 AND CLOSE>中轴参考 AND 涨幅异动;
STICKLINE(转强条件,OPEN,CLOSE,3,0),COLORRED;
DRAWTEXT(转强条件,LOW*0.96,' ★转强'),COLORRED;
长阳柱:=(CLOSE-REF(CLOSE,1))/REF(CLOSE,1)*100>=6.98;
STICKLINE(长阳柱,CLOSE,CLOSE*1,1.7,0),COLOR00DDDD;
STICKLINE(长阳柱,CLOSE,CLOSE*1,0,0),COLOR00AACC;
中阳柱:=(CLOSE-REF(CLOSE,1))/REF(CLOSE,1)*100>4.99;
STICKLINE(中阳柱,OPEN,OPEN*1,1.7,0),COLOR00DDDD;
STICKLINE(中阳柱,OPEN,OPEN*1,0,0),COLOR00AACC;
DRAWTEXT_FIX(1,0.01,0.17,0,GNBLOCK),COLORMAGENTA;
DRAWTEXT_FIX(1,0.01,0.01,0,HYBLOCK),COLORRED;
DRAWTEXT_FIX(1,0.01,0.08,0,DYBLOCK),COLORYELLOW;
2、中轴观察副图公式：
{中轴观察·副图-公式手记-原创}
R1:=100*(HHV(HIGH,21)-CLOSE)/(HHV(HIGH,21)-LLV(LOW,21));
R2:=100*(HHV(HIGH,42)-CLOSE)/(HHV(HIGH,42)-LLV(LOW,42));
成本A:=MA(CLOSE,41)+MA(CLOSE,41)*10/100;
成本B:=MA(CLOSE,23)+MA(CLOSE,23)*5/100;
均价和:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
涨幅达标:=CLOSE>REF(CLOSE,1)*1.05;
MACD值:=((EMA(CLOSE,12)-EMA(CLOSE,26))-(EMA((EMA(CLOSE,12)-EMA(CLOSE,26)),9)))*2;
合力:=(HIGH+LOW+CLOSE)/3;
CCV:=(合力-MA(合力,14))/(0.015*AVEDEV(合力,14));
去噪:=IF((CROSS(R1,20) AND CROSS(R2,20)),0,1);
TYP1:=(HIGH+LOW+CLOSE)/3;
CCI1:=(TYP1-MA(TYP1,14))*1000/(15*AVEDEV(TYP1,14));
条件A:=CROSS(CCV,250) AND CCI1>REF(CCI1,1) AND MACD值>0 AND 去噪 AND C>EMA(C,200);
上轨参考:=SMA(H,14,2)*1.08;
标记1:=FILTER((条件A AND C>上轨参考) OR (REF(条件A,1) AND C>上轨参考),3),COLORYELLOW;
标记2:=CROSS(均价和,成本B) AND 涨幅达标,COLORMAGENTA;
标记3:=CROSS(均价和,成本A) AND 涨幅达标,COLORRED;
统计标记:=BARSLASTCOUNT((标记1 OR 标记2) OR 标记2 OR 标记3)=1;
STICKLINE(统计标记,0,2,2,0),COLORRED;
STICKLINE(统计标记,0,11,0.1,0),COLORYELLOW;
DRAWTEXT(统计标记,8,' 多条件吻合'),COLORYELLOW;
DRAWICON(统计标记,1,9);DRAWICON(统计标记,2,9);
DRAWICON(统计标记,3,9);DRAWICON(统计标记,4,9);
DRAWICON(统计标记,5,9);DRAWICON(统计标记,6,9);
DRAWICON(统计标记,7,9);
DRAWICON(统计标记,8,30);DRAWICON(统计标记,9,29);
DRAWICON(统计标记,10,28);
DRAWICON(统计标记,11.6,1);
3、中轴观察选股公式：
{中轴观察·选股-公式手记-原创}
A1:=REF(EMA((H+L+C)/3,9),1);
A3:=EMA(LLV(LOW,9),3);
中轴:=EMA(A1*2-A3,5);
转强:=OPEN<中轴 AND CLOSE>中轴 AND (CLOSE/REF(CLOSE,1)-1)*100>7;
R1:=100*(HHV(HIGH,21)-CLOSE)/(HHV(HIGH,21)-LLV(LOW,21));
R2:=100*(HHV(HIGH,42)-CLOSE)/(HHV(HIGH,42)-LLV(LOW,42));
成本A:=MA(CLOSE,41)+MA(CLOSE,41)*10/100;
成本B:=MA(CLOSE,23)+MA(CLOSE,23)*5/100;
均价和:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
涨幅达标:=CLOSE>REF(CLOSE,1)*1.05;
MACD值:=((EMA(CLOSE,12)-EMA(CLOSE,26))-(EMA((EMA(CLOSE,12)-EMA(CLOSE,26)),9)))*2;
合力:=(HIGH+LOW+CLOSE)/3;
CCV:=(合力-MA(合力,14))/(0.015*AVEDEV(合力,14));
去噪:=IF((CROSS(R1,20) AND CROSS(R2,20)),0,1);
TYP1:=(HIGH+LOW+CLOSE)/3;
CCI1:=(TYP1-MA(TYP1,14))*1000/(15*AVEDEV(TYP1,14));
条件A:=CROSS(CCV,250) AND CCI1>REF(CCI1,1) AND MACD值>0 AND 去噪 AND C>EMA(C,200);
上轨:=SMA(H,14,2)*1.08;
标记1:=FILTER((条件A AND C>上轨) OR (REF(条件A,1) AND C>上轨),3);
标记2:=CROSS(均价和,成本B) AND 涨幅达标;
标记3:=CROSS(均价和,成本A) AND 涨幅达标;
副图共振:=BARSLASTCOUNT((标记1 OR 标记2) OR 标记2 OR 标记3)=1;
QST:=IF(NAMELIKE('S'),0,1);
QXX:=IF(NAMELIKE('*'),0,1);
QKC:=NOT(CODELIKE('688'));
QBJ:=NOT(CODELIKE('9')) AND NOT(CODELIKE('4'));
风控:=QST AND QXX AND QKC AND QBJ AND BARSCOUNT(C)>=60;
信号观察:风控 AND 转强 AND 副图共振;
五、安装提示
1. 主图、副图、选股分开新建：主图/副图选"技术指标公式"，选股选"条件选股公式"；
2. 电脑端：Ctrl+F → 新建 → 粘贴源码 → 测试公式 → 确定；
3. 手机端：K线→指标→新建副图/主图叠加；选股→自定选股→新建；
4. 若报错，检查AND/OR两侧空格、全角符号、问号"?"；多源码建议先粘贴到Word再复制到通达信。
温馨提示
觉得这套思路对你有启发，点个文章底部❤️推荐，让更多朋友看到这份干货~
