夜雨聆风
《RSI自适应指标》强弱上下轨道线公式源码-多空区域识别!
本期指标说明：
指标先计算RSI价格强弱数值，再根据市值大小和价格波动幅度，自动调整上下两条轨道线的位置。当强弱数值向上穿过上轨时出现一个红箭头，向上穿过下轨时出现红箭头图标，柱状线颜色也随之变化，帮助使用者观察价格所处的强弱区域。
幅图区域使用，新建幅图类型指标，分为文华和通达信两个版本源码。公开发布的是幅图指标，精品指标类型不公开发布，不免Fei提供！
完整版指标文件，记得点赞+转发+爱心，评论“RSI自适应”，记得斯❤我！发您可导入的指标文件！
一、指标源码：主图是精品指标
文华版源码如下：
周期数:=14;
波动周:=20;
长周期:=100;
缩放值:=50;
上市天:=BARSCOUNT(CLOSE);
简模式:=上市天 < 长周期;
昨收价:=REF(CLOSE,1);
RSI值:SMA(MAX(CLOSE-昨收价,0),周期数,1)/SMA(ABS(CLOSE-昨收价),周期数,1)*100,COLORYELLOW;
上界线:70,COLORGRAY,POINTDOT;
下界线:30,COLORGRAY,POINTDOT;
实周期:=MAX(MIN(长周期,上市天-1-波动周),1);
波动值:=STD(CLOSE,波动周);
波均值:=MA(波动值,实周期);
波差值:=STD(波动值,实周期);
标分:=(波动值-波均值)/波差值;
波分数:=IF(波差值>0.001,标分,0);
分范围:=MAX(MIN(波分数,3),-3);
分基准:=1.0+分范围*0.15;
调因子:=MAX(MIN(分基准,1.7),0.8);
股本数:=GETPRICE1(‘流通股本’)*100;
市值额:=股本数*C/1000000;
趋周期:=IF(市值额>300,100,IF(市值额>150,70,IF(市值额>50,40,25)));
可周期:=MIN(趋周期,上市天-1);
上乘数:=IF(市值额>300,7,IF(市值额>150,5.5,IF(市值额>50,4,3.5)));
下乘数:=IF(市值额>300,2.5,IF(市值额>150,3.5,IF(市值额>50,4.5,5.5)));
基准价:=REF(CLOSE,可周期);
趋强度:=(CLOSE-基准价)/基准价*100;
强因子:=趋强度/缩放值;
因范围:=MAX(MIN(强因子,2),-2);
基宽度:=18;
动宽度:=基宽度*调因子;
上线轨:=50+动宽度+因范围*上乘数;
下线轨:=50-动宽度+因范围*下乘数;
超买线:IF(简模式,上界线,上线轨),COLORRED,LINETHICK1;
超卖线:IF(简模式,下界线,下线轨),COLORGREEN,LINETHICK1;
DRAWICON(CROSS(RSI值,超买线),超买线,4);
DRAWICON(CROSS(RSI值,超卖线),超卖线,4);
STICKLINE(RSI值>=超买线,超买线,超买线,1,0),COLORRED;
STICKLINE(RSI值< 超买线,超买线,超买线,1,0),COLORGREEN;
STICKLINE(RSI值<=超卖线,超卖线,超卖线,1,0),COLORGREEN;
STICKLINE(RSI值>超卖线,超卖线,超卖线,1,0),COLORRED;
中位线:50,COLORGRAY,POINTDOT;
通达源码如下：主图是精品指标
N1:=14;
{周期参数一:=14;}
N2:=20;
{周期参数二:=20;}
N3:=100;
{周期参数三:=100;}
N4:=50;
{缩放比值:=50;}
N5:=BARSCOUNT(CLOSE);
{上市总天数:=BARSCOUNT(CLOSE);}
N6:=N5 < N3;
{简易模式开关:=上市总天数 < 周期参数三;}
N7:=REF(CLOSE,1);
{昨日收盘价:=REF(CLOSE,1);}
RSI:SMA(MAX(CLOSE-N7,0),N1,1)/SMA(ABS(CLOSE-N7),N1,1)*100,COLORYELLOW;
{强弱数值:SMA(MAX(收盘价-昨日收盘价,0),周期参数一,1)/SMA(ABS(收盘价-昨日收盘价),周期参数一,1)*100,颜色黄;}
N8:70,COLORGRAY,POINTDOT;
{简易上界线:70,颜色灰,点虚线;}
N9:30,COLORGRAY,POINTDOT;
{简易下界线:30,颜色灰,点虚线;}
N10:=MAX(MIN(N3,N5-1-N2),1);
{实际周期长度:=MAX(MIN(周期参数三,上市总天数-1-周期参数二),1);}
N11:=STD(CLOSE,N2);
{价格波动值:=STD(收盘价,周期参数二);}
N12:=MA(N11,N10);
{波动平均值:=MA(价格波动值,实际周期长度);}
N13:=STD(N11,N10);
{波动标准差:=STD(价格波动值,实际周期长度);}
N14:=(N11-N12)/N13;
{标准分数值:=(价格波动值-波动平均值)/波动标准差;}
N15:=IF(N13>0.001,N14,0);
{波动标准分:=IF(波动标准差>0.001,标准分数值,0);}
N16:=MAX(MIN(N15,3),-3);
{分数范围值:=MAX(MIN(波动标准分,3),-3);}
N17:=1.0+N16*0.15;
{基准分数值:=1.0+分数范围值*0.15;}
N18:=MAX(MIN(N17,1.7),0.8);
{基础调节数:=MAX(MIN(基准分数值,1.7),0.8);}
N19:=FINANCE(40)/100000000;
{市值规模:=FINANCE(40)/100000000;}
N20:=IF(N19>300,100,IF(N19>150,70,IF(N19>50,40,25)));
{趋势周期长:=IF(市值规模>300,100,IF(市值规模>150,70,IF(市值规模>50,40,25)));}
N21:=MIN(N20,N5-1);
{可用周期数:=MIN(趋势周期长,上市总天数-1);}
N22:=IF(N19>300,7,IF(N19>150,5.5,IF(N19>50,4,3.5)));
{高位系数值:=IF(市值规模>300,7,IF(市值规模>150,5.5,IF(市值规模>50,4,3.5)));}
N23:=IF(N19>300,2.5,IF(N19>150,3.5,IF(N19>50,4.5,5.5)));
{低位系数值:=IF(市值规模>300,2.5,IF(市值规模>150,3.5,IF(市值规模>50,4.5,5.5)));}
N24:=REF(CLOSE,N21);
{参考价格:=REF(收盘价,可用周期数);}
N25:=(CLOSE-N24)/N24*100;
{强弱幅度:=(收盘价-参考价格)/参考价格*100;}
N26:=N25/N4;
{幅度因子:=强弱幅度/缩放比值;}
N27:=MAX(MIN(N26,2),-2);
{因子范围值:=MAX(MIN(幅度因子,2),-2);}
N28:=18;
{基础宽幅:=18;}
N29:=N28*N18;
{动态宽幅:=基础宽幅*基础调节数;}
N30:=50+N29+N27*N22;
{完整上轨线:=50+动态宽幅+因子范围值*高位系数值;}
N31:=50-N29+N27*N23;
{完整下轨线:=50-动态宽幅+因子范围值*低位系数值;}
UP:IF(N6,N8,N30),COLORRED,LINETHICK1;
{上轨界线:IF(简易模式开关,简易上界线,完整上轨线),颜色红,线宽1;}
DN:IF(N6,N9,N31),COLORGREEN,LINETHICK1;
{下轨界线:IF(简易模式开关,简易下界线,完整下轨线),颜色绿,线宽1;}
DRAWICON(CROSS(RSI,UP),UP,1);
{画图标(上穿(强弱数值,上轨界线),上轨界线,图标1);}
DRAWICON(CROSS(RSI,DN),DN,1);
{画图标(上穿(下轨界线,强弱数值),下轨界线,图标1);}
STICKLINE(RSI>=UP,UP,UP,1,0),COLORRED;
{画柱线(强弱数值>=上轨界线,上轨界线,上轨界线,1,0),颜色红;}
STICKLINE(RSI<UP,UP,UP,1,0),COLORGREEN;
{画柱线(强弱数值<上轨界线,上轨界线,上轨界线,1,0),颜色绿;}
STICKLINE(RSI<=DN,DN,DN,1,0),COLORGREEN;
{画柱线(强弱数值<=下轨界线,下轨界线,下轨界线,1,0),颜色绿;}
STICKLINE(RSI>DN,DN,DN,1,0),COLORRED;
{画柱线(强弱数值>下轨界线,下轨界线,下轨界线,1,0),颜色红;}
N32:50,COLORGRAY,POINTDOT;
{中位参考线:50,颜色灰,点虚线;}
1、指标公式源码供大家学习研究，不具备操作指导等作用。
2、技术指标是分析辅助工具，大家自行学习灵活运用，盈亏自负。
1、打开软件–进入指标管理器
2、选择指标类型的分组名称，输入指标名称，描述可以不写，选择指标属性，切记属性选择要对哦。
3、复制源码，粘贴源码
4、语法测试，通过，点击确定保存，或者直接加载到图形上。
5、键盘直接输入新建指标名称，软件右下角即可调出指标，选择即可显示出来。
END
立即加星标
每天看好文
点点赞
点转发
点❤️