夜雨聆风
X间隔值:=0.15;
Y间隔值:=0.15;
起点位X值:=X间隔值/10;
起点位Y值:=Y间隔值/10;
概念:=STRCAT('概念: ',GNBLOCK);
DRAWTEXT_FIX(C>0,0*起点位X值,0.5*起点位Y值,0,概念),COLORYELLOW;
地域:=STRCAT(DYBLOCK,'');
DRAWTEXT_FIX(C>0,0*起点位X值,3.5*起点位Y值,0,地域),COLORWHITE;
行业:=STRCAT(HYBLOCK,'');
DRAWTEXT_FIX(C>0,4*起点位X值,3.5*起点位Y值,0,行业),COLORWHITE;
LTSZ:=STRCAT(STRCAT('总市值:',CON2STR(FINANCE(41)/100000000,2)),' 亿元');
DRAWTEXT_FIX(C>0,8*起点位X值,3.5*起点位Y值,0,LTSZ),COLORWHITE;
操盘线:MA(C,7);
IF(C>=操盘线,操盘线,DRAWNULL),COLORRED,LINETHICK2;
IF(C<操盘线,操盘线,DRAWNULL),COLORGREEN,LINETHICK2;
生命线:MA(C,55);
IF(生命线>=REF(生命线,1),生命线,DRAWNULL),COLORBLUE,LINETHICK2;
IF(生命线<REF(生命线,1),生命线,DRAWNULL),COLORLICYAN,LINETHICK2;
涨停板1:=C=H AND C/REF(C,1)>1.0975 AND C/REF(C,1)<1.11 AND FINANCE(3)=1;
涨停板2:=C=H AND C/REF(C,1)>1.1985 AND C/REF(C,1)<1.21 AND FINANCE(3)=3;
涨停板:=涨停板1 OR 涨停板2;
K线实体:=ABS(C-O)/REF(C,1);
双倍量:=V/REF(V,1)>=2.6;
倍量0:=C>O AND 双倍量 AND C>EMA(C,13) AND V=HHV(V,6);
位置要求:=L/EMA(C,13)<1.05 AND C>生命线 AND (C/生命线)<=1.16;
SPX0:=H/REF(C,1)>=1.06 AND H=HHV(H,6) AND 倍量0 AND H/C>1.005 AND C/REF(C,1)>1.015 AND 位置要求 AND K线实体>0.01 AND FINANCE(3)=1;
SPX1:=H/REF(C,1)>=1.11 AND H=HHV(H,6) AND 倍量0 AND H/C>1.005 AND C/REF(C,1)>1.015 AND 位置要求 AND K线实体>0.02 AND FINANCE(3)=3;
SPX2:=SPX0 OR SPX1;
SPX3:=SPX2 AND NOT(EXISTR(SPX2,6,1));
试盘K线:=SPX3 AND COUNT(SPX3,20)=1;
STICKLINE(试盘K线,H,L,0,0),COLORFF55FF;
STICKLINE(试盘K线,C,O,3.1,0),COLOR880088;
STICKLINE(试盘K线,C,O,2.6,0),COLORAA00AA;
STICKLINE(试盘K线,C,O,1.9,0),COLORCC00CC;
STICKLINE(试盘K线,C,O,1.1,0),COLOREE00EE;
STICKLINE(试盘K线,C,O,0.2,0),COLORFF44FF;
SPZQ:=BARSLAST(试盘K线);
洗盘不破:=IF(SPZQ>0,COUNT(EMA(C,13)<REF(EMA(C,13),1),SPZQ)<2,0);
洗盘K00:=C<O AND H<REF(H,1);
洗盘K0:=EXIST(试盘K线,10) AND IF(SPZQ>0,H<HHV(H,SPZQ+1),0) AND C>=EMA(C,13) AND L<=REF(C,SPZQ) AND C<O AND IF(SPZQ>0,COUNT(洗盘K00,SPZQ)<2,0);
洗盘K:=洗盘K0 AND COUNT(洗盘K0,10)=1;
DRAWTEXT(洗盘K,H*1.01,'↙震仓K'),COLORWHITE;
XPZQ:=BARSLAST(洗盘K);
TPZQ:=BARSLAST(试盘K线);
突破量能:=V/REF(V,1)>=1.5 OR V>MA(V,5);
DIF:=EMA(C,12)-EMA(C,26);
DEA:=EMA(DIF,9);
MACD金叉:=CROSS(DIF,DEA);
起爆涨幅:=C/REF(C,1)>=1.035;
突破K0:=EXIST(试盘K线,13) AND TPZQ<=13 AND C>REF(C,TPZQ) AND C>O AND 突破量能 AND MACD金叉 AND 起爆涨幅;
突破K1:=EXIST(试盘K线,13) AND TPZQ<=13 AND C>REF(C,TPZQ) AND 涨停板 AND 突破量能 AND 起爆涨幅;
突破K2:=EXIST(试盘K线,13)
AND TPZQ<=13
AND H>REF(H,TPZQ)
AND C>=REF(C,TPZQ)
AND 突破量能
AND 起爆涨幅;
突破K3:=突破K0 OR 突破K1 OR 突破K2;
突破次数:=COUNT(突破K3, TPZQ+1);
突破K:=突破K3 AND 突破次数=1;
STICKLINE(突破K,O,C,3.1,0),COLOR00AAFF;
STICKLINE(突破K,O,C,2.1,0),COLOR00BBFF;
STICKLINE(突破K,O,C,1.5,0),COLOR00CCFF;
STICKLINE(突破K,O,C,1,0),COLOR00DDFF;
STICKLINE(突破K,O,C,0.6,0),COLOR00EEFF;
STICKLINE(突破K,O,C,0.2,0),COLOR00FFFF;
STICKLINE(突破K,H,L,0,0),COLOR00FFFF;
STICKLINE(突破K,O,L,0,0),COLORFFFFFF;
STICKLINE(突破K,O,MAX(O,REF(H,XPZQ)),3.1,0),COLOR555555;
STICKLINE(突破K,O,MAX(O,REF(H,XPZQ)),2.6,0),COLOR777777;
STICKLINE(突破K,O,MAX(O,REF(H,XPZQ)),1.9,0),COLOR999999;
STICKLINE(突破K,O,MAX(O,REF(H,XPZQ)),1.1,0),COLORCCCCCC;
STICKLINE(突破K,O,MAX(O,REF(H,XPZQ)),0.2,0),COLORFFFFFF;
DRAWTEXT(突破K,L*0.98,'↖突破K'),COLORWHITE;
异动K0:=IF(XPZQ>0,H>REF(H,XPZQ),0) AND H/REF(C,1)>1.03 AND C>O AND EXIST(试盘K线,10) AND EXIST(洗盘K,SPZQ) AND C<REF(H,XPZQ) AND NOT(EXIST(突破K,SPZQ));
异动K1:=EXISTR(试盘K线,1,1) AND C>O AND C<REF(H,1) AND C>REF(C,1) AND H<REF(H,1);
异动K2:=异动K0 OR 异动K1;
异动K:=异动K2 AND COUNT(异动K2,10)=1;
STICKLINE(异动K,H,L,0,0),COLOR0000FF;
STICKLINE(异动K,C,O,3.1,0),COLOR000099;
STICKLINE(异动K,C,O,2,0),COLOR0000BB;
STICKLINE(异动K,C,O,1,0),COLOR0000DD;
STICKLINE(异动K,C,O,0.2,0),COLOR0000FF;
DRAWTEXT(异动K,L*0.99,'↖异动K'),COLORWHITE;
DRAWTEXT(试盘K线 AND NOT(突破K),(C+O)*0.5,'试盘K'),COLORWHITE;
KK1:=SUMBARS(洗盘K,1);
KK2:=SUMBARS(试盘K线,1);
STICKLINE(KK1<10 AND KK2<11 AND XPZQ>0,REF(H,XPZQ),REF(H,XPZQ),3.1,0),COLORWHITE;