ARTICLE · 1393644
Excel必学函数SUMIF条件求和新手超实用教程
点击蓝字 关注我们
SUMIF函数可以对范围中符合指定条件的值求和,该函数拥有十分强大的条件求和功能,在工作中有极其广泛的应用。
今天这篇就是专为Excel 新手准备的保姆级SUMIF教程.
一 SUMIF函数语法
首先要搞懂函数的基础用法:
=SUMIF(range, criteria, [sum_range])
SUMIF具体参数:
•Range必需。用于条件计算的单元格区域
•Criteria必需。用于确定对求和单元格的条件,其形式可以是数字、表达式、单元格引用、文本或函数。
•Sum_range可选。求和区域是可选项,如果你省略了最后一个求和区域,Excel 会自动把前面“【找条件的区域】”当成要加总的区域来计算。
二 SUMIF案例
【1】精准匹配:按部门统计总月薪
要求:统计指定部门总月薪
公式:=SUMIF(C2:C16,A19,F2:F16)
注
C2:C16:条件区域,部门列。
A19:条件,引用「技术部」的单元格。
F2:F16:求和区域,月薪列。

【2】按数字大小筛选求和
要求:统计月薪大于20000总月薪。
公式:=SUMIF(F2:F16,">20000")
注
F2:F16:条件区域, 月薪列
">20000":比较条件(英文双引号)

也可以条件引用单元格的方式。
公式:=SUMIF(F2:F16,">"&B18)
注:
• F2:F16:条件区域, 月薪列
• ">"&B18:">"比较运算符是文本,必须加双引号,& 是连接符,把运算符和单元格数字连接成完整条件。B18引用单元格

【3】排除某个目标
要求:统计除技术部以外部门总月薪
公式:=SUMIF(C2:C16,"<>技术部",F2:F16)
注:
C2:C16:条件区域,部门列。
"<>技术部":<> 表示「不等于」,和文字英文双引号,写成 "<>技术部"。
F2:F16:求和区域,月薪列。

【5】多列区域求和
要求:按计划/实际统计销售总量(计划/实际交替排列)
公式:=SUMIF($B$2:$I$2,J$2,$B3:$I3)
注
• $B$2:$I$2:条件区域,条件区域不一定非得是一列,横着摆照样能用,这就是「多列区域求和」的关键。
• J$2:条件,引用表头「计划」。列相对、行绝对,向右填充到 K 列时变成 K$2(「实际」)。
• $B3:$I3:求和区域 。列绝对、行相对,向下填充时依次变成 $B4:$I4、$B5:$I5……

注意:选中单元格,按F4,则单元格绝对引用,再按一次F4,则单元格相对引用锁定行,再按一次F4,则单元格相对引用锁定列,尽量避免一个个输入“$”符号。
易错点
1. 引号:文本条件、含 > < <> 的条件必须英文半角双引号;单元格引用绝不能加引号。
2. 区域等长:条件区域和求和区域必须行列数一致、逐格对应,错位会算出一串看不懂的数。
3. 严格不等:> 不含等于,>= 才含;<> 排除的是整段文本完全一致的单元格。
4. 第三参数可省:判断和求和都在同一列时,写两个参数就够了。
5. 通配符:* 任意多个字符、? 单个字符、~ 转义。默认精确匹配,别把「包含」当成默认行为。
6. 填充前检查 $:向右填充锁行号(如 J$2),向下填充锁列标(如 $B3)。
7. 多条件改 SUMIFS:SUMIF 只管一个条件;部门 + 城市这类双条件求和,要用 SUMIFS。
END

拾
光

岁
月
不
语
笔记留声
















































































