夜雨聆风
与众不同!【主力倍量、强倍量】公式 源码
点击公众号+星标⭐关注我们
下面开始今天的分享：
【主力倍量/强倍量】 公式
今天周末，给大家分享一个倍量公式，祝大家周末愉快！
这个指标呢，我一般不会去单独分享的，因为它比较普通且常见，由于这是一位粉丝在后台私信我说:”老师，您这里有倍量指标吗？我说有”！所以，这才制作了一下，但我要让它变得不再简单，经过我的加工优化后呢，在此发布分享给更多的有缘人！
周末在家有空的同学，可以好好学习研究研究哦，我相信在我这里的铁粉，每天看我发的公式，一定能够组合成一套属于自己的操作系统！
好了，下面言归正传。
大家知道吗？倍量的表示方法其实非常简单，就一句话（一句源码就可以搞定）的事情，不过出现的信号也较多，会让你眼花缭乱
，但是在这里，既然咱要分享这个公式，那就不能让它这么简单！咱得让它稍微有价值！！
这里还是要简单说明一下的哈：
1、红色实心柱：强势倍量；
（它的含义是：成交量是前一日的2倍以上，且涨幅超过3%）；
2、粉红色实心柱：普通倍量；
（它的含义是：成交量是前一日的2倍以上，但涨幅或实体阳线条件稍弱）；
3、黄色实心柱：主买点信号；
（它的含义是：经过严格条件过滤的高成功率买点，但信号较少哦
）；
4、棕色实心柱 ：次买点信号；
（它的含义是：条件相对宽松的买点信号）；
5、紫色空心柱：普通上涨量；
(这个很简单，就是当日上涨但非倍量的普通成交量）；
6、灰色实心柱 – 普通下跌量；
（这个很好理解，就是当日下跌的成交量）；
☆接下来再讲一个重点！那就是[风险控制]!
1、任何买点都必须有前期倍量柱确认；
2、主买点成功率较高，但也要设止损；
3、次买点需结合大盘环境，弱势行情慎用！
4、单日涨幅过大的倍量柱（超过7%）要警惕次日回调。
好了，差不多了，也不方便讲的太详细，还有哪里不清楚的，来留言区哈
指标无未来函数，以下举例：
1、主力倍量副图公式：
{微信公众号:股民指标库}
V1:=VOL;
C1:=CLOSE;
O1:=OPEN;
H1:=HIGH;
L1:=LOW;
{微信公众号:股民指标库}
MA5:=MA(C1,5);
MA10:=MA(C1,10);
MA20:=MA(C1,20);
MA60:=MA(C1,60);
MA5V:MA(V1,5),COLORWHITE,LINETHICK1;
MA20V:MA(V1,20),COLOR00FFFF,LINETHICK1;
{微信公众号:股民指标库}
实体涨幅:=(C1-O1)/O1*100;
倍量:=V1/REF(V1,1)>=2
AND (C1-REF(C1,1))/REF(C1,1)*100>3
AND C1>MA5
AND 实体涨幅>2
AND (H1-C1)/(H1-L1+0.001)<0.3;
强势倍量:=倍量 AND (C1-REF(C1,1))/REF(C1,1)*100>5;
DRAWICON(强势倍量,V1*1.2,1);
{微信公众号:股民指标库}
倍量天数:=BARSLAST(倍量);
回调天数条件:=倍量天数>=2 AND 倍量天数<=5;
倍量当天量:=REF(V1,倍量天数);
回调缩量:=COUNT(V1<倍量当天量*0.8, 倍量天数-1)>=倍量天数-2;
倍量最低:=REF(L1,倍量天数);
倍量实体中位:=REF((O1+C1)/2,倍量天数);
回调不破:=L1>=倍量最低 AND L1>=倍量实体中位*0.99;
放量启动:=V1>MA5V*1.5
AND V1>REF(V1,1)*1.5
AND V1>倍量当天量*0.7;
{微信公众号:股民指标库}
价格突破:=C1>REF(HHV(H1,倍量天数+2),1)
AND C1>MAX(MA5,MA10)
AND C1>MA20;
多头排列:=MA5>MA10 AND MA10>MA20;
趋势向上:=MA20>REF(MA20,5) AND MA60>REF(MA60,20);
DIFF:=EMA(C1,12)-EMA(C1,26);
DEA:=EMA(DIFF,9);
MACD金叉:=CROSS(DIFF,DEA);
主买点:=回调天数条件
AND 回调缩量
AND 回调不破
AND 放量启动
AND 价格突破
AND 多头排列
AND 趋势向上
AND 倍量天数<=5
AND 倍量天数>=3;
次买点:=回调天数条件
AND 回调不破
AND 放量启动
AND 价格突破
AND C1>MA20
AND 倍量天数<=5;
{微信公众号:股民指标库}
STICKLINE(强势倍量, V1, 0, 3, 0), COLORRED;
STICKLINE(倍量 AND NOT(强势倍量), V1*1.05, 0, 2.5, 0), COLORLIRED;
STICKLINE(主买点, V1*1.25, 0, 3.5, 0), COLORYELLOW;
STICKLINE(次买点 AND NOT(主买点), V1*1.15, 0, 2.8, 0), COLORBROWN;
STICKLINE(C1>=REF(C1,1) AND NOT(倍量) AND NOT(主买点) AND NOT(次买点),
V1, 0, 2, 1), COLORMAGENTA;
STICKLINE(C1<REF(C1,1) AND NOT(倍量) AND NOT(主买点) AND NOT(次买点),
V1, 0, 2, 0), COLORGRAY;
DRAWTEXT(强势倍量, V1*1.25, ‘★强倍’), COLORYELLOW;
DRAWTEXT(倍量 AND NOT(强势倍量), V1*1.20, ‘★倍量’), COLORLIRED;
DRAWTEXT(主买点, V1*1.35, ‘↖主买’), COLORGREEN;
DRAWTEXT(主买点, V1*1.28, ‘高成功’), COLORWHITE;
DRAWTEXT(次买点 AND NOT(主买点), V1*1.29, ‘↖次买’), COLORCYAN;
DRAWTEXT(次买点 AND NOT(主买点), V1*1.18, ‘谨慎’), COLORWHITE;
{微信公众号:股民指标库}
DRAWTEXT_FIX(1,0.41,0.02,0,’倍量信号:’),COLORWHITE;
DRAWTEXT_FIX(1,0.48,0.02,0,CON2STR(COUNT(倍量,20),0)),COLORLIRED;
DRAWTEXT_FIX(1,0.52,0.02,0,’主买点:’),COLORWHITE;
DRAWTEXT_FIX(1,0.58,0.02,0,CON2STR(COUNT(主买点,20),0)),COLORGREEN;
DRAWTEXT_FIX(1,0.62,0.02,0,’次买点:’),COLORWHITE;
DRAWTEXT_FIX(1,0.68,0.02,0,CON2STR(COUNT(次买点,20),0)),COLORCYAN;
2、强势倍量选公式：
{微信公众号:股民指标库}
MA5:=MA(C,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
{微信公众号:股民指标库}
BLL:=V/REF(V,1)>=2.0;
ZFF:=(C-REF(C,1))/REF(C,1)*100>=4.0;
STY:=C>O AND (C-O)/(H-L+0.001)>0.5;
SYD:=(H-C)/(H-L+0.001)<0.3;
QS:=MA5>MA10 AND MA10>MA20 AND C>MA20;
CXG:=C=HHV(C,10);
HSS:=V/CAPITAL*100>=3.0;
{微信公众号:股民指标库}
强势倍量选:BLL AND ZFF AND STY AND SYD AND QS AND CXG AND HSS;
你的每次【点赞+爱心❤】，都是我分享好指标的动力！
你的每次【点赞+爱心❤】，都是我分享好指标的动力！
你的每次【点赞+爱心❤】，都是我分享好指标的动力！
免责声明
。